Criptografía (CCLV): Cifrado César en Excel

Ya puse una entrada con un script en python para cifrar y descifrar utilizando el cifrado César.

Y ahora, en este post incluyo el cifrado y descifrado utilizando este mismo criptosistema en Excel.

La programación la he realizado con Visual Basic para Aplicaciones (VBA) y, como en los posteriores posts que pondré con la automatización en Excel de tareas que ya haya hecho en python, no he pensado en "traducir" directamente el código de un lenguaje a otro, sino que la forma de implementar un mismo asunto puede variar sustancialmente, aunque evidentemente el resultado final pretenda ser el mismo.

Asimismo, en estos posts relativos a Excel no entraré en el detalle de los sistemas criptográficos y otros asuntos a implementar, ya que los he explicado profusamente en entradas anteriores, si no que me limitaré a poner el código y un ejemplo de su funcionamiento.

Dicho lo anterior, en este caso el código es el siguiente:

' CIFRADO CÉSAR:
'
' Cifra y descifra textos en claro y criptogramas, respectivamente,
' utilizando el cifrado César.
'
' http://mikelgarcialarragan.blogspot.com/

Option Explicit
Public TEXTO_CLARO As Range
Public CLAVE As Range
Public CRIPTOGRAMA As Range
Public Sub Cifrar()
    Dim Caracter As Integer

    Range("TEXTO_CLARO").Value = A_Z(UCase(Replace(Range("TEXTO_CLARO").Value, " ", "")))
    
    If Len(Range("TEXTO_CLARO").Value) = 0 Then
        MsgBox "Introduzca el texto en claro a cifrar. Sólo caracteres alfabéticos [A-Z], 'Ñ' excluida.", vbOKOnly + vbCritical, "¡Error!"
    Else
        If Range("CLAVE").Value < 1 Or Range("CLAVE").Value > 26 Then
            MsgBox "El desplazamiento debe seer un número comprendido entre 1 y 26.", vbOKOnly + vbCritical, "¡Error!"
            Range("CLAVE").Value = 3
        Else
            Range("CRIPTOGRAMA").Value = ""
            For Caracter = 1 To Len(Range("TEXTO_CLARO").Value)
                Range("CRIPTOGRAMA").Value = Range("CRIPTOGRAMA").Value & chr((Asc(Mid(Range("TEXTO_CLARO").Value, Caracter, 1)) - 65 + Range("CLAVE").Value) Mod 26 + 65)
            Next
        End If
    End If

End Sub
Public Sub Descifrar()
    Dim Caracter As Integer

    Range("CRIPTOGRAMA").Value = A_Z(UCase(Replace(Range("CRIPTOGRAMA").Value, " ", "")))
    
    If Len(Range("CRIPTOGRAMA").Value) = 0 Then
        MsgBox "Introduzca el criptograma a descifrar. Sólo caracteres alfabéticos [A-Z], 'Ñ' excluida.", vbOKOnly + vbCritical, "¡Error!"
    Else
        If Range("CLAVE").Value < 1 Or Range("CLAVE").Value > 26 Then
            MsgBox "El desplazamiento debe seer un número comprendido entre 1 y 26.", vbOKOnly + vbCritical, "¡Error!"
            Range("CLAVE").Value = 3
        Else
            Range("TEXTO_CLARO").Value = ""
            For Caracter = 1 To Len(Range("CRIPTOGRAMA").Value)
                Range("TEXTO_CLARO").Value = Range("TEXTO_CLARO").Value & chr((Asc(Mid(Range("CRIPTOGRAMA").Value, Caracter, 1)) + 65 - Range("CLAVE").Value) Mod 26 + 65)
            Next
        End If
    End If

End Sub
Function A_Z(Cadena As String) As String
    Dim Caracter As Integer

    For Caracter = 1 To Len(Cadena)
        Select Case Asc(Mid(Cadena, Caracter, 1))
            Case 65 To 90:
                A_Z = A_Z & Mid(Cadena, Caracter, 1)
        End Select
    Next

End Function

Ejemplo de funcionamiento:

- Cifrar:

- Descifrar:

Quizás también te interese: